REM LISTING OF FILE: MAIN.PRG

REM START ADDRESS: $0801
REM END ADDRESS+1: $85E1
REM SIZE (BYTES):   32224

4 ::::POKE52,142:POKE56,142:CLR:POKE198,0
5 T$="":DIMNA$(15):GOSUB40:GOSUB19000:GOTO50
7 VZ=VA+2*V:POKEVZ,FNLB(ZV):POKEVZ+1,ZV/KP:RETURN
9 VZ=142.5*KP+2*V:ZV=PEEK(VZ)+KP*PEEK(VZ+1):RETURN
10 POKEA0,FNLB(F*KP):POKEA1,F:POKEA2,FNLB(T*KP):POKEA3,T:POKEA4,FNLB(L*KP)
11 POKEA5,L:SYSM64K:RETURN
12 POKEA0,F:POKEA2,FNLB(T*KP):POKEA3,T:POKEA4,FNLB(L*KP)
13 POKEA5,L:SYSSB:RETURN
20 OPEN15,8,15,"I":PRINT#15,"S0:MAIN":CLOSE15:SAVE"MAIN",8:END
30 POKEA1,Y:POKEA3,DY:POKEA4,CO:POKEA0,X:POKEA2,DX:SYSWN:RETURN
40 POKE792,193:POKE808,234:POKE56333,129:RETURN
41 POKE56333,127:POKE808,237:POKE792,71:RETURN
50 VB=150*KP:WN=153.5*KP:CTY=143*KP:CLN=24:NC=PEEK(CTY+1023)-3:PRS=148*KP
55 PTY=PRS+32:MP=155.5*KP:TR=142*KP:SO=158*KP:LG=147*KP:DTA=6*KP:SG=-1
60 OPEN8,8,8,"0:NAMES"+STR$(PEEK(PRS+29))+",S,R":FORI=0TO15:INPUT#8,NA$(I):NEXTI
61 FORI=0TO9:INPUT#8,RK$(I):NEXTI:CLOSE8:NA$="":P$="0 PCS":A=PRS+80
62 Z=PEEK(A):IFZTHENNA$=NA$+CHR$(Z):A=A+1:GOTO62
70 SN=PEEK(PR+26):FORI=1TOSQR((SN+1)*1.9):READX$:NEXTI:DATAHIDES,TOBACCO,SUGAR
86 DF=PEEK(PRS-3):GOSUB12000:DAY=FNDP(LG+4*PEEK(LG)-3)
88 YR=INT(DAY/360):DAY=DAY-YR*360
990 CC=PEEK(PRS+25):CP=CTY+CLN*CC:GOSUB9180:GOSUB12500
995 ME=FNDP(PTY+3):NN=PEEK(CP+3):LL=2:PX=1:MT=-1
996 Z=PEEK(PRS+18):IFZ=1THENGOSUB1000:GOTO2999
997 SL=SGN(Z):IFZAND4THENPOKEPRS+18,ZAND3:GOSUB3937
998 GOTO3200
1000 GOSUB12500
1015 ZZ=INT(DAY/30):GOSUB1099
1017 ZZ=DAY-ZZ*30+1:T$=T$+STR$(ZZ)+","+STR$(YR+1560+SN*20)
1020 T$=T$+" CONTINUE TRAVEL PARTY STATU PERSONAL STATU SHIP&S LO MAP"
1023 ZZ=(LL=0)*(((PD=0)OR(PD>24))+.5)
1025 T$=T$+" CITIE TAKE SUN SIGH"
1027 IFLL=1THENT$=T$+" SEARC"
1028 IFLLAND2THENT$=T$+" SAVE GAM"
1030 X=10:Y=4:GOSUB8000:A=CP:GOSUB2950:IFC=1THENRETURN
1040 IFC<8THENA=PTY:ONCGOSUB0,2500,1900,7000,2299,2000,6500:GOTO1000
1090 IFC=8-(ZZ<>0)THENGOSUB2400:GOTO1000
1095 GOTO1000
1098 Z=YR+1560+SN*20
1099 T$=MID$("JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDECJAN",ZZ*3+1,3):RETURN
1900 PRINT"":X=9:Y=2:DX=29:DY=9:CO=3:GOSUB30:T$="":IFPEEK(PRS+20)THENT$="(MARRIED)"
1910 PRINT:PRINT,"PERSONAL STATUS: "T$
1920 FORI=1TO4:Z=IAND3:GOSUB2195:PRINT," "CO$F$,:Z=PEEK(PRS+13+(IAND3))
1925 IFZTHENPRINTRK$(Z):GOTO1935
1926 Z=FNEX(PRS+8+(IAND3)):IFZ>1THENPRINT"(LETTER OF MARQUE)":GOTO1935
1927 IFZ>-1THENPRINT"(NO TITLE)":GOTO1935
1928 IFZ>-4THENPRINT"WARY":GOTO1935
1929 PRINT"HOSTILE"
1935 NEXTI:GOSUB8435:PRINT," AGE:"YR+25,T$" HEALTH"
1940 PRINT," WEALTH:"FNDP(PRS+2)*10"GOLD PCS.":PRINT," LAND:"PEEK(PR+5)*50"ACRES"
1980 POKE214,12:PRINT
1982 GOSUB8420:PRINT,"REPUTATION: ":PRINT,"  "F$;:GOSUB8445:PRINTF$
1983 GOSUB2980:RETURN
2000 CO$="":GOSUB12500:POKEVB+16,40:POKEVB+17,108
2005 PRINT"  CITY INFORMATION":PRINT:POKE53269,1:MO=2:POKEA5,0
2007 POKE214,4:PRINT:PRINT"SELECT A CITY:":PRINT,"(DONE)":T$="VILLAHERMOSA"
2008 ZZ=FNDP(45):POKEA2,PEEK(ZZ+3):POKEA3,PEEK(ZZ+4):POKEA4,12:FORK=0TONC
2010 A=CTY+K*CLN+12:POKEA0,FNLB(A):POKEA1,A/KP:SYSM64K:IFK/3=INT(K/3)THENPRINT
2020 Z=PEEK(A-9):PRINTMID$(CO$,Z+1,1);:IF(PEEK(A-12)AND128)=0THENPRINT"";
2022 PRINT" "T$;:NEXTK
2025 IFPEEK(VB+14)=0THEN2025
2030 C=3*(INT(PEEK(VB+17)/8)-15)+INT(PEEK(VB+16)/53):IFC<0THENRETURN
2035 IFC>NCTHENC=NC
2040 A=CT+CL*C:GOSUB2140:GOTO2025
2100 GOSUB2900:T$="":GOSUB12500
2140 POKEA0,19:POKEA1,0:POKEA2,16:POKEA3,8:POKEA4,3:SYSWN:PRINT"":GOSUB2950
2150 PRINT,,C$
2160 IFNOTPEEK(A)AND128THENPRINT,,"  NO INFO":RETURN
2165 Z=PEEK(A+3):GOSUB2195:PRINT,," ( "CO$;F$")"
2170 Z=PEEK(A+4)AND15:IFZTHENPRINT,,Z;"FORT(S)"
2180 PRINT,,PEEK(A+5)*10;"SOLDIERS.":PRINT,,(PEEK(A+6)+1)*100;"CITIZENS."
2185 IFPEEK(A+7)THENPRINT,," GOLD:"PEEK(A+7)",000"
2190 T$="STRUGGLINGSURVIVING PROSPERINGWEALTHY   ":Z=INT(PEEK(A+8)/64)
2193 PRINT,," "MID$(T$,Z*10+1,10):RETURN
2195 F$="SPANISHENGLISHFRENCH DUTCH  PIRATE ":CO$=MID$(F$,Z*8+1,1)
2196 F$=MID$(F$,Z*8+2,7)
2197 Z=LEN(F$):IFRIGHT$(F$,1)=" "THENF$=LEFT$(F$,Z-1):GOTO2197
2199 F$=F$+" ":RETURN
2250 FORK=4TO7:AA=TR+24+K*8:IF(PEEK(AA+3)AND63)<>CCORPEEK(AA)=0THEN2280
2261 Z=PEEK(AA+1):GOSUB2290
2264 X=4:Y=8:FF=35:GOSUB8590:DZ=1:POKEAA+3,RND(0)*NC
2265 F$="STREET":T$=CO$:GOSUB8290:IFV<>1THEN2280
2266 POKEAA,0:F$="SPANIARD":GOSUB3391:SG=4:Z=PEEK(PR+6):GOSUB8430:CO$="YOUR "+T$
2270 FF=44:X=1:Y=1:GOSUB8590:A=TR+8:GOSUB3590
2280 NEXTK:RETURN
2290 CO$=RK$((ZAND7)+2)+" "+NA$(INT(Z/8)):RETURN
2295 CO$=RK$(PEEK(PRS+NN+13))+" "+NA$:RETURN
2299 FORK=0TO2:A=TR+8*K:GOSUB2300:NEXTK:RETURN
2300 IFPEEK(A)=0THENRETURN
2310 POKE53280,1:POKE53282,9:POKE53283,0:SYSVB+3:POKE53265,0:POKE648,228:AA=A
2320 ZZ=PEEK(A):X=PEEK(A+1):Y=PEEK(A+2)
2325 F=15:T=216:L=4:GOSUB12:POKE53281,8:X=(X-4)*64-32:Y=(Y-6)*32:POKEMP+15,255
2328 F=4:T=232:L=4:GOSUB10
2330 POKEMP+6,FNLB(X):POKEMP+7,X/KP:POKEMP+8,FNLB(Y):POKEMP+9,Y/KP:SYSMP
2332 F=0:L=80/KP:Z=PEEK(648):T=Z:GOSUB12:GOSUB5990
2335 FORJ=0TO3:IF(ZZAND(2^J))=0THENX=(JAND1)*21:Y=2+6*(JAND2):GOSUB2390
2340 NEXTJ:POKE53264,0:POKESX,182:POKESY,151:POKEVB+15,0:POKESC,1:SYSVB
2345 POKE53280,0:IFAA=TRTHENPRINT"  PIRATE TREASURE MAP"
2346 IFAA=TR+8THENZ=PEEK(PRS+6):GOSUB8430:PRINT"  MAP TO LOST "T$
2347 IFAA=TR+16THENPRINT"  MAP TO LOST INCA TREASURE!"
2350 IFPEEK(AA)AND16THENA=PEEK(AA+3)*CLN+CTY:GOSUB2950:PRINT"  ...SOMEWHERE NEAR "C$
2360 POKESP,183+(AA=TR+8):POKE53269,1:IFPEEK(56320)AND16THEN2360
2370 GOSUB12500:POKEVB+15,1:RETURN
2390 T$="    MISSING!   ":GOSUB8005:RETURN
2400 IFLL>=2THEN2450
2405 F$="":ZZ=3:GOSUB9000:X=6:Y=7:FORK=0TO2:AA=TR+8*K:Z=PEEK(AA)
2410 IFPEEK(PTY+1)<>PEEK(AA+1)ORPEEK(PTY+2)<>PEEK(AA+2)ORZ=0THEN2445
2415 Z=PEEK(PRS+6):GOSUB8430:CO$="YOUR "+T$:C1=15:C2=7
2420 F$="TREASURE":IFK=1THENF$="RESCUE"+STR$(ZAND1):ZZ=((Z-1)AND7)+8:C1=0:C2=10
2422 XX=1:X=-2:Y=9:GOSUB8100:FF=47+K:IFK=1THENPOKEA0,15:POKEA1,ZZ:SYSWN+18
2425 ZZ=-INT(RND(0)*9+5)*100*(K=0):IFK=2THENZZ=10000
2430 SG=3:X=5:Y=1:GOSUB8590:ZZ=-ZZ:GOSUB3990:POKEAA,0
2435 IFK<>1THENC1=8:C2=0:GOSUB7900:GOTO2445
2440 Y=8:FF=43:GOSUB8590:A=TR+16:GOSUB3590:C1=26:C2=PEEK(PRS+6):GOSUB7900
2441 C=6:GOSUB8400:FORI=4TO7:POKETR+24+I*8,0:NEXTI
2445 NEXTK:IFF$=""THENFF=34:GOSUB8590
2449 RETURN
2450 GOSUB12500:GOSUB2495:IFA$<>"2"THENGOSUB2480
2451 FF=55:GOSUB8600:T$=T$+"":F$=T$
2452 T$=F$:X=6:Y=6:GOSUB8000
2454 IFC<3THENGOSUB2495:IFA$="2"THENRETURN
2455 IFC<3THENGOSUB2480:RETURN
2456 IFC>3THENZZ=C:GOTO2470
2460 T$="FORMAT DISK":GOSUB3970:IFC<>3THEN2452
2461 OPEN15,8,15,"N0:P!SAVE,P3":CLOSE15:OPEN8,8,8,"FAME,S,W"
2462 A$=CHR$(13):FORI=0TO9:PRINT#8,"---";A$;"--";A$;0:NEXTI:CLOSE8:GOTO2452
2470 GOSUB2495:IFA$="3"THEN2475
2472 T$="GAME SAVE DISK":GOSUB2490:IFA$<>"3"THEN2452
2475 F$="SAVEGAME"+STR$(ZZ-3):BF=TR:LN=7*KP:GOSUB17700
2476 T$="SAVE COMPLETED":GOSUB7999
2480 T$="GAME DISK SIDE 2":GOSUB2490:IFA$<>"2"THEN2480
2485 RETURN
2490 T$="INSERT "+T$+" THEN PRESS TRIGGE":X=6:Y=16:GOSUB8000
2495 POKE53269,0:OPEN15,8,15,"I0":OPEN2,8,2,"#1":PRINT#15,"U1";2;0;18;0
2496 PRINT#15,"B-P";2;163:GET#2,A$:CLOSE2:CLOSE15:RETURN
2500 PRINT""
2505 POKEA0,2:POKEA1,1:POKEA2,19:POKEA3,9:POKEA4,6:SYSWN:T$="":GOSUB9180
2510 PRINT""NA$"&S PARTY":PRINTT$"CREW:"FNDP(PTY+3)"MEN"
2520 PRINTT$"CANNON:"PEEK(PTY+5):PRINTT$"GOLD:"FNDP(PTY+7)P$
2525 Z=KP*PEEK(PTY+9)+PEEK(PTY+13):PRINTT$"FOOD:"INT(Z/FNDP(PTY+3))"DAYS"
2530 GOSUB8440:PRINTT$"CREW IS "F$
2535 PRINTT$"GOODS:"PEEK(PTY+10)"TONS":PRINTT$""X$":"PEEK(PTY+11)"TONS"
2560 T$="PRISONERS ":FORI=88TO95:ZZ=PEEK(TR+I):IFZZ=0THEN2570
2565 Z=ZZAND127:GOSUB2290:T$=T$+CO$:F$=" (HUNTER ":IFZZ>127THENF$=" (PIRATE "
2566 T$=T$+F$
2570 NEXTI:IFLEN(T$)>12THENX=1:Y=14:GOSUB8005
2580 T$="SHIPS ":GOSUB5920:X=15:Y=10:GOSUB8005
2590 GOSUB2980:RETURN
2950 C$="":FORI=A+12TOA+23:C$=C$+CHR$(PEEK(I)):NEXTI:IFMO=2THENRETURN
2955 Z=LEN(C$):IFRIGHT$(C$,1)=" "THENC$=LEFT$(C$,Z-1):GOTO2955
2960 RETURN
2980 XS=X:YS=Y:T$=" PRESS TRIGGER TO CONTINU":X=9:Y=21:GOSUB8000:X=XS:Y=YS
2985 POKEA0,9:POKEA1,21:POKEA2,28:POKEA3,2:POKEA4,CO:SYSWN:RETURN
2990 RR=0:IFPEEK(VB+14)=1THEN2990
2992 RR=RR+1:IFPEEK(VB+14)=0THENONRR/199+1GOTO2992,2994
2993 POKEVB+16,0:RETURN
2994 GOSUB2980:GOTO2993
2999 GOSUB8500:GOSUB5000
3000 GOSUB12500:A=CP:GOSUB2950:PRINT:PRINT"  YOU HAVE ARRIVED AT THE LOVELY"
3014 IFPEEK(CP)AND64THENPRINT"  INLAND VILLAGE OF "C$".":GOTO3020
3015 PRINT"  SEA-SIDE TOWN OF "C$"."
3020 ZZ=PEEK(CP+4):IFZZ>1THENPRINT" "ZZ"FORTS GUARD THE HARBOR ENTRANCE."
3021 IFZZ=1THENPRINT"  A FORT GUARDS THE HARBOR ENTRANCE."
3022 Z=NN:GOSUB2195:POKEPRS+25,CC
3024 PRINT"  THE "CO$;F$"FLAG FLIES OVER THE TOWN."
3026 IFCC=PEEK(PRS-1)THENPRINT"  THE TREASURE FLEET IS IN THE HARBOR!":DZ=DZ+1
3027 IFCC=PEEK(PRS-2)THENPRINT"  THE SILVER TRAIN IS IN TOWN!":DZ=DZ+1
3030 F$="TOWN1":X=19:Y=8:C1=0:C2=5:GOSUB8100
3032 T$="SAIL INTO HARBO":IFLLAND1THENT$="MARCH INTO TOW"
3035 T$="WILL YOU "+T$+" ATTACK TOW SNEAK INTO TOW LEAVE TOW"
3040 Z=PEEK(CP+11):VV=VVAND3:IFVT<>CPTHENMT=-1:VV=0
3042 VT=CP:X=1:Y=6:GOSUB8000:IFC=4THENGOSUB12500:GOTO2999
3050 IFC=2THEN3100
3055 IFC=3THENVV=VVOR10:GOTO3800
3060 CX=RND(0)*(FNEX(PRS+8+NN)+FNEX(CP+9)-ME/100):IFCX>-.5ORPEEK(CP+4)=0THEN3200
3070 GOSUB12500:T$="AS YOU APPROACH THE TOWTHE FORT OPENS FIRE":X=1:Y=2
3075 GOSUB8005:IFCX>-1ORLL<>2THEN3032
3080 T$="ONE OF YOUR SHIPS IS SUNK":X=9:Y=12:GOSUB8000:GOSUB4900:GOTO2999
3099 GOSUB2980:RETURN
3100 FT=0:XM=0:HT=0:FORI=1TO2:IFPEEK(PRS-I)=CCTHENPOKECP+5,FNRG(PEEK(CP+5)+10)
3101 NEXTI:IFLL=2THEN3110
3102 IFFNDP(PTY+3)>PEEK(CP+5)*15ORPEEK(CP+4)=0ORPEEK(CP+5)<10THEN3122
3103 GOSUB6700:ZZ=0:GOSUB3980:IFV=0THEN2999
3104 IFPEEK(CP+4)=0THEN3160
3106 GOTO3122
3110 IFPEEK(CP+4)=0THENF$="STREET":T$="TOWN":GOTO3125
3112 FT=1:SA=DTA+KP+21*7:POKESA+2,PEEK(CP+5)/2+.5:POKESA+3,12*(PEEK(CP+4)AND7)
3115 POKESA,8:POKESA+1,NN:POKESA+4,0:GOSUB5460:IFK=0THEN2999
3120 POKECP+5,PEEK(CP+5)/2+FNGS(59)/10+.5
3122 X=3:Y=3:FF=61:GOSUB8590:T$="FORT":F$="COURT"
3125 Y(1)=3+RND(X)*3:T(1)=5+PEEK(CP+4)
3130 GOSUB8450:T(0)=PEEK(CP+5)*10+5:Y(0)=ME-XM:GOSUB8300:ZZ=XM:GOSUB3980
3150 IFV=0ORDLTHENC=-4:GOSUB8400:C=-(8+NN):GOSUB8400:GOTO2999
3160 POKECP+5,(FNGS(56)+9)/10:GOSUB8180:T$="CITIZENS":GOSUB3610:GOTO2999
3200 C1=1:GOSUB7890:GOSUB12500:POKE(CP),PEEK(CP)OR128
3210 A=CP:GOSUB2140:F$="VILLAGE"+STR$(3-LL):X=1:Y=3:C1=0:C2=9:GOSUB8100:GOTO3300
3250 T$="WE DO NOT TRADE WITH PIRATES"
3260 IF(NN=0)AND(PEEK(CP+8)>(PEEK(DT+249)+25*FNEX(PR+13)))THENGOSUB7999:GOTO3300
3261 F$="MERCHANT":X=11:Y=9:GOSUB8099
3262 K=0:IFPEEK(PTY+15)<2ORLL=3THEN3264
3263 T$="WOULD YOU CARE TSELL ANY SHIPS":MO=0:GOSUB3285
3264 IFLL=3OR(K=0ANDPEEK(PTY+20)<8)THEN3270
3265 T$="WOULD YOU LIKE ANSHIPS REPAIRED":MO=1:GOSUB3285
3270 Z=PEEK(CP+8)*(1+ABS(6-MN)/6):ZZ=PEEK(CP)
3271 FORI=0TO3:T(I)=INT((1+RND(0))*Z*(PEEK(CP+6)+10)/150):P(I)=INT(Z/50+3-I/2)
3272 IFZZAND2^(3-I)THENP(I)=INT(P(I)/2+1)
3273 IFI>1AND((ZZAND2^(6-I))<>0)THENP(I)=2*P(I)
3275 NEXTI:T(0)=15*T(0):P(0)=1:IFT(0)>2500THENT(0)=2500
3276 P(4)=5:T(4)=0:IFMT>=0THENT(0)=MT
3278 C=0:T$="MERCHANT":XM=FNDP(PT+7):GOSUB8210:MT=FNGS(7)
3279 IFABS(XM-FNDP(PT+7)>20)THENPOKECP+8,PEEK(CP+8)*.95+12
3280 GOTO3300
3285 X=18-14*MO:Y=MO:GOSUB8005
3286 T$=" NO THANKS"
3290 K=0:FORI=1TOPEEK(PTY+15):X=PEEK(PTY+19+I):ZZ=XAND7:GOSUB4290:K=K-(X>7)
3291 Z=(XAND248)/8:IFMO=0THENZ=10-Z
3292 T$=T$+" "+F$+"  ":IFZTHENT$=T$+STR$((ZZ+1)*Z*50)+" GOLD PC":GOTO3294
3293 T$=T$+" NO DAMAG"
3294 NEXTI:X=20-14*MO:Y=3+MO:GOSUB8000:C=INT(C/2-.5):IFC<0THENRETURN
3295 X=PEEK(PTY+20+C):Z=(XAND248)/8:IFMO=0THENZ=10-Z
3296 ZZ=Z*((XAND7)+1)*10*(.5+(MO=0)):GOSUB3990:IFZZ<0THEN3286
3297 IFMO=1THENPOKEPTY+20+C,XAND7:T$="SHIP REPAIRE":GOSUB7999:IFK>1THEN3286
3298 IFMO=0THENZZ=C:GOSUB4905:T$="SHIP SOL":GOSUB7999:IFPEEK(PTY+15)>1THEN3286
3299 RETURN
3300 ZZ=3:GOSUB9000:VV=VVOR-(PEEK(CP+6)<6)
3303 A=CP:GOSUB2950:T$=C$+" IS BUSTLINWITH ACTIVITY.  DO YOU "
3305 IFVVAND1THENT$=T$+""
3306 T$=T$+"VISIT THE GOVERNO VISIT A TAVER"
3308 T$=T$+" TRADE WITH A MERCHAN":IFVVAND8THENT$=T$+""
3309 T$=T$+" DIVIDE UP THE PLUNDE CHECK INFORMATIO LEAVE TOW"
3320 X=12:Y=15:GOSUB8000:PRINT"";:IFC=6THENGOSUB1000:GOTO3303
3325 IF(VVAND(2^(C-2))AND9)<>0THENT$="YOU CAN&T DO THAT":GOSUB7999:GOTO3303
3330 ONCGOTO0,3340,3400,3250,3900,0,3332
3332 ZZ=INT(ME*(FNEX(PTY+17)-3)/15):IFZZ<=-METHENZZ=-ME+1
3335 X=6:Y=16:T$="ROLL CALL REVEALTHAT"+STR$(-ZZ)+" CREW MEMBERHAVE DESERTED"
3336 IFZZ<-1THENGOSUB3975:GOSUB8000
3337 C=TR+88+RND(0)*8:Z=PEEK(C)AND127:IFZ=0ORLL<>2THEN3339
3338 GOSUB2290:POKEC,0:T$=CO$+" JUMPOVERBOARD AND ESCAPES":GOSUB8000
3339 GOSUB8500:GOTO2999
3340 AX=0:VV=VVOR1:F$="GOVERNOR":RD=14:GOSUB8098
3341 GOSUB2295:T$="%MY DEAR "+CO$+"":V=0:FORI=0TO3
3342 A=PRS+64+NN*4+I:IFPEEK(A)THENZ=I:GOSUB2195:IFVTHENT$=T$+"AN"
3343 IFPEEK(A)=1THENT$=T$+"WE ARE ALLIEWITH THE "+F$:V=VOR1
3344 IFPEEK(A)=255THENT$=T$+"WE ARE AT WAWITH THE "+F$:V=VOR2
3345 NEXTI:IF(VAND2)=0ORFNEX(PRS+8+NN)<2THENT$=T$+".":GOTO3347
3346 T$=T$+"I CHARGE YOU TO SEEOUT AND DESTROY OUENEMY&S SHIPS AND TOWNS!"
3347 IFVTHENX=2:Y=2:GOSUB8000
3348 GOSUB2250
3350 FORK=88TO95:Z=PEEK(TR+K):IFZ<128ORINT(Z/32)-4<>NNTHEN3354
3351 POKETR+K,0:POKEPRS+8+NN,(PEEK(PRS+8+NN)+(ZAND7)/2+1)AND255
3352 Z=ZAND127:GOSUB2290:FF=54:X=2:Y=12:GOSUB8590
3354 NEXTK:A=PR+13+NN:Z=PEEK(A)+1:LN=FNEX(A-5)-INT(Z^2+2):IFLN<0ORZ>9THEN3360
3355 POKEA,Z:POKEA-5,PEEK(A-5)-LN:Z=NN:GOSUB2195
3356 C$=F$:CO$=RK$(PEEK(A))+" "+NA$:X=-17:Y=9:F$="AWARD":RD=14:GOSUB8099
3357 X=1:Y=1:FF=7:C1=2:C2=PEEK(A)+NN*64:GOSUB7900:SG=0:GOSUB8590
3358 IFLN>0THENPOKEPRS+5,FNRG(PEEK(PRS+5)+LN):ZZ=LN*50:Y=10:FF=13:GOSUB8590
3359 Y=2:IFPEEK(PRS+6)<4AND(PEEK(PRS+18)AND1)=0THENGOSUB9250
3360 AA=TR+88+INT(RND(0)*8):Z=PEEK(AA)AND127:IFZ=0THEN3367
3362 GOSUB2290:FF=53:ZZ=((ZAND7)+1)*50*INT(RND(0)*3+1):X=4:Y=3:GOSUB8590
3364 IFC=5THENZZ=-ZZ:GOSUB3990:POKEAA,0
3367 X=2:Y=3:A=CP:GOSUB2950:IFFNEX(PRS+8+NN)<-3THEN3388
3368 ZZ=20*(4-FNEX(PRS+8+NN)^3):IFZZ>=10THEN3380
3369 Z=PEEK(CP+11):LN=(ZAND12)/4:IFZAND224THEN3710
3370 ZZ=(PEEK(PR+13+NN)+FNDP(PR+2)/999+DF/2)/(LN+1):IFZZ<.5ORPEEK(PR+20)THEN3388
3371 GOSUB3390:Z=LN*2+1+NN*32:GOSUB2290:IFPEEK(PRS+23)=4THENZZ=ZZ*2
3372 X=1:Y=1:FF=15:GOSUB8590:GOSUB2295:IFC<>7THEN3378
3373 IFZZ<4THENGOSUB8445:C$=F$:FF=16+INT(ZZ/2):GOSUB8590:GOTO3300
3374 FF=18:GOSUB8590:IFC<>6THEN3300
3375 F$="STREET":T$="SUITOR":GOSUB8290:IFV=0THEN3300
3376 GOSUB12500:POKEPRS+20,LN+1:F$="WEDDING":X=-4:Y=9:GOSUB8099
3377 FF=19:X=10:Y=1:SG=1:GOSUB8590:POKECP+11,PEEK(CP+11)OR64:GOTO3300
3378 FF=45:IFZZ*RND(0)<=2THEN3300
3379 VV=VVAND247:GOSUB8590:POKECP+11,PEEK(CP+11)OR128:C=21:GOSUB8400:GOTO3300
3380 Z=NN:GOSUB2195:CO$=F$:FF=5:X=2:Y=4:IFFNEX(PRS+NN+8)<0THENFF=6
3381 GOSUB8590:IFC<>5THEN3300
3382 GOSUB3990:IFZZ<0THEN3300
3385 POKECP+9,0:POKEPRS+8+NN,0:C=8+NN:GOSUB8400:GOSUB8400:GOTO3300
3388 IFAX=0THENT$="THE GOVERNOR HANOTHING TO SAY":X=5:Y=20:GOSUB8000
3389 GOTO3300
3390 F$="BRIDE"+STR$((PEEK(CP+11)AND12)/4)
3391 X=-17:Y=9:C1=0:K=(PEEK(CP+11)AND3)+(CCAND4)+490:C2=PEEK(DTA+K):GOSUB8100
3392 POKEA0,15:POKEA1,PEEK(DTA+K+8):SYSWN+18
3393 POKEA0,11:POKEA1,(CCAND3)+11:SYSWN+18:RETURN
3400 AX=0:F$="TAVERN":GOSUB8097
3410 ZZ=INT((FNEX(PRS+4)+7-DF)*(RND(0)+1)*PEEK(CP+6)/9)
3415 Z=(4-DF)*6:IFFNDP(PTY+3)<4*ZANDZZ<ZTHENZZ=Z
3416 Z=16*(PEEK(PTY+15)*2+PEEK(PTY+14)):IF(ME+ZZ)>ZTHENZZ=Z-ME
3420 IF(ZZ<=2)OR(VVAND2)THEN3500
3425 F$="CREW":RD=14:GOSUB8097:GOSUB8420:GOSUB2295
3430 T$="'LOOK! IT&S THAT "+F$+"SEA-DOG: "+CO$
3435 T$=T$+"'A ROWDY GROUP OF"+STR$(ZZ)+" MEASKS TO JOIN YOUR CREWDO YOU"
3440 T$=T$+" SIGN THEM UP TURN THEM AWAY":X=6:Y=0:GOSUB8000:IFC<>5THEN3500
3445 GOSUB3980
3500 VV=VVOR2:GOSUB2250:ZZ=5+INT(RND(0)*10)
3505 A=CTY+CLN*INT(RND(0)*(NC+1)):IF(PEEK(A)AND128)AND(ZZ<>5)THEN3500
3506 IFPEEK(A)AND128THEN3550
3507 GOSUB2950:F$="TRAVEL":RD=13:GOSUB8095
3510 T$="A TRAVELLER FRO"+C$+" OFFERS TSELL YOU INFORMATIOFOR"+STR$(ZZ)
3515 T$=T$+"0 GOLD PIECESDO YOU AGREE YE N":X=10:Y=13:GOSUB8000
3520 IFC<>5THEN3550
3525 GOSUB3990:IFZZ<0THEN3550
3530 POKEA,PEEK(A)OR128:GOSUB2140:GOSUB2950:GOSUB2980:T$="TRAVELLERS"
3540 CX=CP:CP=A:CC=(CP-CTY)/CLN:GOSUB3610:CP=CX:A=CP:CC=(CP-CTY)/CLN:GOSUB2950
3550 IFPEEK(TR)=31ORRND(0)>.2THEN3600
3565 F$="MAPPER":RD=13:GOSUB8098:FF=4:X=1:Y=3:GOSUB8590:IFC<>5THEN3600
3570 ZZ=50:GOSUB3990:IFZZ<0THEN3600
3580 A=TR:GOSUB3590:GOTO3600
3590 F$="TREAS":GOSUB12900:GOSUB5950:V=21:ZV=A:GOSUB7:V=22:ZV=NC:GOSUB7
3595 GOSUB12950:GOTO2300
3600 Z=TV:TV=DAY+YR*360:IFTV-Z>30THENF$="TAVERN NEWS":RR=2:GOSUB7010:AX=1
3605 T$="PATRONS":GOSUB3610
3606 IFAX=0THENT$="NOTHING HAPPENAT THE TAVERN":X=8:Y=20:GOSUB8000
3607 GOTO3300
3610 A$=" NO INQUIR":A=CP:GOSUB2950:K=0:FORI=4TO7:A=TR+24+8*I
3612 IFPEEK(A)=0THEN3620
3613 Z=0:FORJ=3TO7:Z=Z-((PEEK(A+J)AND63)=CC):NEXTJ:IFZ=0THEN3620
3615 Z=PEEK(A+1):GOSUB2290:A$=A$+" "+CO$+"":T(K)=I:K=K+1
3620 NEXTI:IFK=0THENRETURN
3625 T$="THE "+T$::FF=8:GOSUB8610:T$=T$+A$:A$=T$
3630 X=10:Y=9:GOSUB8000:IFC<7THENRETURN
3640 C=T(C-7):AA=TR+24+C*8:Z=PEEK(AA+1):GOSUB2290
3650 J=0:FORI=7TO3STEP-1:IF(PEEK(AA+I)AND63)=CCTHENZZ=PEEK(AA+I-1)AND63:J=I
3655 NEXTI:IFJ>3THENA=CTY+CLN*ZZ:GOSUB2950
3658 IFJTHENPOKEAA+J,CC+128:C1=9:C2=(C-4)*64
3665 IFJ>3THENT$=CO$+" LEFFOR "+C$+"A FEW MONTHS AGO":C2=C2+ZZ:GOSUB7900
3670 IFJ=3THENT$=CO$+" INOW IN "+C$+"":C2=C2+CC:GOSUB7900
3690 X=2+C:Y=14-C:GOSUB8000:T$=A$:IFK>1THEN3630
3695 A$="":RETURN
3710 CO$="INFORMER":IFPEEK(CP+11)AND64THENCO$="WIFE"
3715 GOSUB3390:FF=46:X=1:Y=1:GOSUB8590
3720 GOSUB4270:GOSUB4275:GOTO3300
3800 IFFNEX(CP+9)*FNEX(PRS+4)>-RND(0)*50THEN3200
3810 FF=2:X=6:Y=10:GOSUB8590:F$="STREET":T$="GUARD"
3820 DZ=1:GOSUB8290:GOTO2999
3900 T$="DIVIDE PLUNDER":GOSUB3970:IFC<>3THEN3300
3901 GOSUB3910:GOTO3300:REM DISTRIBUTE BOOTY
3910 AA=FNDP(PTY+7):ZZ=INT(AA/ME*.8+.5):Z=INT(SQR(ZZ)/2.3):IFZ>3THENZ=3
3912 POKEPRS+4,((SQR(ZZ)+FNEX(PRS+4)+1)/2)AND255
3915 GOSUB8441:CO$=F$:FF=10:X=2:Y=0:GOSUB8595
3925 GOSUB8445:ZZ=2*DF+2:CO$="AS CAPTAIN ("+F$:X=4:Y=8:FF=11:GOSUB8600
3926 ZZ=INT(AA*.05*(1+DF)):T$=T$+STR$(ZZ*10)+" GOLD PCS":GOSUB8005:GOSUB3995
3931 GOSUB3960:FF=9:GOSUB8600:T$=T$+"":DF=DF+1:GOSUB8445:DF=DF-1
3932 IFDF<3THENT$=T$+" ADVANCE TO "+F$+" LEVEL"
3935 GOSUB8000:IFC=8THENDF=DF-(DF<4):POKEPRS-3,DF:V=73:ZV=DF:GOSUB7
3936 IFC=7THENT$="END THE GAME":GOSUB3970:IFC=3THEN21000
3937 FF=28:X=1:Y=1:GOSUB8595
3938 POKEPRS+7,240:XM=0:T$="":FORJ=0TO3:ZZ=26:GOSUB9000:NEXTJ:AA=FNDP(PTY+7)
3940 IFAA=0THENZ=FNDP(PRS+2):ZZ=-.1*Z:GOSUB3995:AA=ZZ
3942 POKEPTY+7,FNLB(AA/10):POKEPTY+8,AA/10/KP:Z=PEEK(PTY+20)AND7:POKEPT+14,Z*2+2
3945 POKEPTY+20,Z:POKEPTY+5,Z*2+6:FORI=10TO13:POKEPTY+I,0:NEXTI:POKEPTY+9,15
3946 POKEPTY+15,1:ZZ=16+FNEX(PRS+4)-ME:GOSUB3980:POKEPRS+7,0:VV=0
3950 RETURN
3960 X=6:Y=13:IFPEEK(PRS+18)AND1THENFF=14:GOSUB8590:GOTO21000
3961 GOSUB8435:IFZ=4THENFF=60:GOSUB8590:GOTO21000
3962 RETURN
3970 T$="ARE YOU SURYOU WANT T"+T$+" YE N":X=10:Y=17:GOSUB8000:RETURN
3975 GOSUB3980:ZZ=-ZZ/(ME-ZZ)*FNDP(PTY+7):GOSUB3990:RETURN
3980 ME=FNDP(PTY+3)+INT(ZZ):POKEPTY+3,FNLB(ME):POKEPTY+4,ME/KP
3981 IFME=0THENZZ=1:GOTO3980
3982 RETURN
3990 ZZ=FNDP(PTY+7)-ZZ:IFZZ<0THENT$="NOT ENOUGH GOLD":GOSUB7999:RETURN
3992 POKEPTY+7,FNLB(ZZ):POKEPTY+8,ZZ/KP:RETURN
3995 ZZ=FNDP(PRS+2)+ZZ:POKEPRS+2,FNLB(ZZ):POKEPRS+3,ZZ/KP:RETURN
4000 V=0:Z=NN:GOSUB2195:IFDD>12THENF$="UNKNOWN "
4015 T$="'SAIL HO!THE LOOKOUT REPORTS SAIL ON THE HORIZON":X=2:Y=14
4020 IFDF<2THENT$=T$+"'WE&RE IN "+F$+"WATERSTHE MASTER REMINDS"
4025 T$=T$+"SHALL WE INVESTIGAT CONTINUE VOYAG":GOSUB8000:IFCAND1THENRETURN
4030 ZV=INT(RND(0)*(ME/50+WA/6-FNEX(CP+9))/3):IFZV>4THENZV=4
4040 SA=DTA+7*(ZV+5*PEEK(CP+3))+KP
4041 IF(RND(0)<.4)OR(DD>12)THENSA=DTA+7*INT(RND(0)*20)+KP
4042 IFCC=PEEK(PRS-1)ANDRND(0)>WA/24THENSA=DTA+7*20+KP
4049 ZZ=5:GOSUB4300
4060 ZZ=PEEK(SA):GOSUB4290:GOSUB2197
4070 T$="SHE LOOKS LIKE "+F$+"CAPTAINSHALL WE INVESTIGAT SAIL AWA"
4080 X=1:Y=16:GOSUB8000:NN=PEEK(SA+1)
4085 HT=0:IFPEEK(SA+4)<6ORFNEX(PRS+8+NN)>=0THEN4100
4090 Z=INT((NN+RND(0))*32):IFNN=4THENZ=INT((PEEK(CP+3)+RND(0))*32)
4091 IFZ=0THEN4090
4092 GOSUB2290:DZ=INT((ZAND7)/3):HT=Z:Z=DZ*20+1:GOSUB8421
4093 T$="'ARRRGH!; IT&S THE "+F$+"PIRATE":IFNN<>4THENT$=T$+"-HUNTER"
4094 T$=T$+": "+CO$+"!HE&S CHASING US, CAPTAIN!'"
4095 X=2:Y=2:GOSUB8005:C=3
4100 Z=NN:GOSUB2195:IFC<>3THENRETURN
4105 ZZ=NN:GOSUB4310
4110 T$="SHE&S FLYING "+F$+"COLORS, CAPTAINSHALL WE CLOSE FOR BATTL"
4120 T$=T$+" HAIL FOR NEW SAIL AWA":X=2:Y=14:GOSUB8000
4125 IF(RND(0)<(DF/3))ANDHTTHENV=1:RETURN
4130 IFC=5THENRETURN
4131 IFC=4ANDFNEX(PRS+NN+8)>-4THENF$="SHIP&S NEWS":RR=2:TV=DAY+YR*360:GOTO7010
4135 POKECP+9,(FNEX(CP+9)+(DD<7))AND255:V=1:RETURN
4140 T$="CAPTAIN":F$="DECK":T(0)=FNGS(59):Y(1)=7.9-FNGS(9)/16:IFHTTHENT$=CO$
4145 Z=PEEK(SA+4):Y(0)=ME-XM:T(1)=Z-INT(LN/16):DZ=(7ANDHT)/3
4150 GOSUB8300:ZZ=XM:GOSUB3980:IFV=0THENWA=WA+16:C=-4:GOSUB8400:GOSUB8400:RETURN
4152 C1=4:GOSUB7880
4155 XX=1:X=-11:Y=9:F$="PLUNDER":RD=12:GOSUB8099
4156 SG=1:ZZ=PEEK(SA):GOSUB4290:T$="%CAPTAIN, WE&VE CAPTURE"
4157 IFHTTHENZ=HT:GOSUB2290:T$=T$+CO$+" AN"
4158 T$=T$+"A"+STR$(CX)+" GUN "+F$+"OF"+STR$(ZZ*20+20)+" TONS. WE ":GOSUB8580
4159 T$=T$+"HAVSPACE FOR"+STR$(Z)+" TONS IN THHOLD. SHALL WE KEEP HER?"
4160 T$=T$+" YES, SEND A PRIZE CRE NO, PLUNDER AND SINK HE":X=1:Y=1:GOSUB8000
4161 C=C+(HT<>0):IFC=6ORPEEK(PTY+15)>7THEN4200
4164 Z=PEEK(PTY+15):POKEPTY+15,Z+1:POKEPTY+20+Z,PEEK(SA)+8*INT(LN/16)
4165 POKEPT+14,PEEK(PT+14)+PEEK(SA)*2+2
4170 IFZ*8>METHENZZ=Z*8-ME:GOSUB3980
4200 C=4:GOSUB8400:T$="CREWMEN"
4210 IFNN<>4THENC=-NN-8:GOSUB8400:IFDD<(5+PEEK(SA))THENGOSUB9900:GOSUB3610
4212 IFHT=0THEN4219
4213 Z=HT:GOSUB2290:X=8:Y=4:FF=1:C=0:IF(NNAND3)=0THENGOSUB8590
4214 IFC=6THENGOSUB4270:GOTO4219
4215 IFC=7THENGOSUB4275:GOTO4219
4217 FORI=88TO95:IFPEEK(TR+I)=0THENPOKETR+I,HT+(NNAND4)*32:I=99
4218 NEXTI
4219 T(0)=INT((PEEK(CP+8)+64)/16*PEEK(SA+5)*RND(0)):T(1)=(1+RND(0))*PEEK(SA+2)
4220 FORI=2TO4:T(I)=PEEK(SA+6)*RND(0)^2:P(I)=0:NEXTI:T$="LEAVE BEHIND":T(4)=CX/2
4225 POKEPTY+17,(PEEK(PTY+17)+1-(PEEK(SA+4)>5))AND255:P(0)=0:P(1)=0
4230 GOSUB8210:ZZ=INT(PEEK(SA+2)*(FNEX(PRS+4)+5)*RND(0)/10):IFZZ<2THEN4265
4240 T$="CAPTAIN"+STR$(ZZ)+" SAILORWISH TO JOIN OUR CREW TAKE THE LEAVE THE"
4250 X=2:Y=16:GOSUB8000
4260 IFC=2THENGOSUB3980:GOSUB8500
4265 RETURN
4270 T$="THE TREASURE FLEE":A=1:C$="SPAIN":GOTO4280
4275 T$="THE SILVER TRAI":A=2:C$="PERU"
4280 Z=FNEX(PRS-A):Y=10+A:IFZ>=0THENC1=19+A:C2=Z:GOSUB7900:A=CTY+Z*CLN:GOSUB2950
4285 T$=T$+"IS IN "+C$+"":X=3:GOSUB8000:RETURN
4290 F$="PINNACE     SLOOP       BARQUE      CARGO FLUYT MERCHANTMAN FRIGATE   "
4292 F$=F$+"  WAR GALLEON GALLEON     FORT":Z=(ZZAND7)*12:F$=MID$(F$,Z+1,12)
4293 IF(ZZAND7)=5ANDSN<4THENF$="FAST GALLEON"
4294 IFZZAND248THENF$=F$+" (DAMGD)"
4296 RETURN
4300 X=PEEK(SA):IFX=5ANDSN<4THENX=8
4305 F$="SHIP"+STR$(X):X=-19*SGN(ZZ):Y=1:C1=14:C2=9:GOSUB8100
4310 T$="326501":POKEA0,9:POKEA1,(ASC(MID$(T$,ABS(ZZ)+1))AND7)+8:SYSWN+18:RETURN
4900 V=0:ZZ=INT(RND(0)*PEEK(PTY+15)):GOTO4910
4905 V=1
4910 IFPEEK(PTY+15)=1THEN4950
4915 Z=(PEEK(PTY+20+ZZ)AND7)*2+2:CX=PEEK(PTY+14):POKEPTY+14,CX-Z:CX=(CX-Z)/CX
4920 FORI=ZZTO10:POKEPTY+20+I,PEEK(PTY+21+I):NEXTI:POKEPTY+15,PEEK(PTY+15)-1
4925 IFVTHEN4949
4930 ZZ=FNDP(PTY+7)*(1-CX):GOSUB3990
4940 FORI=9TO12:POKEPTY+I,INT(CX*PEEK(PTY+I)):NEXTI
4945 POKEPTY+5,INT(CX*PEEK(PTY+5))
4949 RETURN
4950 GOSUB12500:X=3:Y=9:C1=9:C2=13:F$="ISLAND":GOSUB8100:X=1:Y=1:FF=30:GOSUB8595
4955 F$="ISLAND":GOSUB12900:GOSUB5950:GOSUB12950:SL=0:GOSUB4990
4960 X=1:Y=14:FF=31:GOSUB8590:RETURN
4990 Z=FRE(0):GOSUB3960
4992 POKEPRS+7,240:XM=0:T$="":FORJ=0TO6+FNEX(PRS+4)/2:ZZ=27:GOSUB9000:NEXTJ:AA=0
4995 GOSUB3940:F=0:T=(TR+24)/KP:L=.4:GOSUB12:GOSUB8435:X=7:Y=8:IFZ=4THEN3960
4996 FF=56+Z:GOSUB8590:DF=DF-SGN(DFAND3):POKEPRS-3,DF:GOSUB8445:CO$=F$:RETURN
5000 Z=-1:GOSUB8700:GOSUB8500:F$="":GOSUB12900:IFSL<2THENSK=2:GOSUB5950
5010 IFSLTHENF=142.5:T=VA/KP:L=.5:GOSUB10:V=18:ZV=1:GOSUB7:GOTO5090
5040 V=23:ZV=CP:GOSUB7:V=22:ZV=NC:GOSUB7:V=19:ZV=0:GOSUB7
5090 GOSUB12500:POKES+12,132:POKES+13,74:IFLL=0THENPOKES+11,129
5095 F=15:T=216:L=4:GOSUB12:F=4:T=232:GOSUB10:IFWA>15THENPOKEPR+60+PEEK(CP+3),CC
5096 F=6:T=142.5:L=.5:GOSUB10:V=79:ZV=T*KP:GOSUB7
5098 SL=2:ZV=INT(3.5-ABS(MN-8)/3):V=12:GOSUB7:V=4:ZV=WA:GOSUB7:POKES+18,128
5100 Z=186.5:GOSUB12970
5104 POKES+13,128:LN=PEEK(A0):GOSUB12500:GOSUB5990
5105 LL=FNGS(5):PD=FNGS(38):F=VA/KP:T=142.5:L=.5:GOSUB10
5107 CP=FNGS(23):WA=FNGS(4):DD=FNGS(26):CC=(CP-CTY)/CLN:ZZ=INT(FNGS(20)/32)+1
5110 GOSUB9000:NN=PEEK(CP+3):ONLNGOTO5450,5300,5350,5365,5000
5115 GOSUB1000:GOTO5000
5300 V=11:GOSUB9:T$="CAPTAIN, WE HAVE ONL"+STR$(ZV)+" DAY&S FOOD LEFT"
5310 X=8:Y=4:IFZVTHEN:GOSUB8000:GOTO5000
5320 FF=38:GOSUB8590:POKEPTY+9,5:ZZ=-ME/3:GOSUB3975:GOTO5000
5350 ZZ=PEEK(PRS+128):FF=37:X=8:Y=5:GOSUB8590:V=0:GOSUB4910
5355 GOTO5000
5365 LL=LLOR2:RETURN
5450 GOSUB4000:FT=0:IFV=0THENWA=WA+16:GOTO5000
5455 GOSUB5460:GOTO5000
5460 LN=INT(RND(0)*3):IFPEEK(PTY+15)=1THEN5500
5465 Z=ME-PEEK(PTY+15)*8+8:ZZ=PEEK(PTY+5):IFZZ>Z/4THENZZ=INT(Z/4)
5470 T$="WE HAVE"+STR$(Z)+" MEN AND"+STR$(ZZ)+"CANNON READY FOR BATTLE"
5472 T$=T$+"WINDS ARE "+MID$(" LIGHTMEDIUMSTRONG",LN*6+1,6)+".  WHIC"
5475 T$=T$+"SHIP WILL YOU COMMAND ":GOSUB5920:X=3:Y=3:GOSUB8000
5480 Z=PEEK(PTY+20):POKEPTY+20,PEEK(PTY+16+C):POKEPTY+16+C,Z
5500 PRINT"":VV=0:XM=FNGS(8):IFFTTHENGOSUB6700
5510 F$="SHIPS":GOSUB12900:V=8:ZV=XM:GOSUB7:V=34:ZV=FT:GOSUB7:V=13:ZV=LN:GOSUB7
5540 V=35:ZV=CP:GOSUB7:V=41:ZV=031:GOSUB7:V=76:ZV=SA:GOSUB7:SK=3
5555 GOSUB5950:DZ=0:POKE214,20:PRINT:ZZ=PEEK(PTY+20)AND7:GOSUB4290:PRINT" "F$"   ";
5560 ZZ=PEEK(SA):GOSUB4290:POKE211,20:POKE53270,8+16*FT:IFFTTHENF$="FORT"
5565 PRINT""F$:PRINT"    GUNS,     MEN","   GUNS,     MEN"
5570 PRINT" NO DAMAGE","NO DAMAGE":PRINT" GUNS LOADED",:IFFT=0THENPRINT"BATTLE SAILS";
5600 GOSUB12950
5605 K=0:ME=FNDP(PTY+3)
5610 ONPEEK(A0)GOTO5620,5630,5640,5650,5660,5670,5680,5690,5700,5710,5720,5730
5620 T$="RELOADING":GOTO5635
5630 T$="GUNS LOADED"
5635 POKE214,23:PRINT:PRINT"                   ":PRINT" "T$;:GOTO5600
5640 GOTO5600
5650 T$=MID$(" LIGHTMEDIUMSTRONG",FNGS(13)*6+1,6)+" WINDS FROM THE "
5651 Z=INT(FNGS(8)/16)*3+1
5652 T$=T$+MID$("S  SSWSW WSWW  WNWNW NNWN  NNENE ENEE  ESESE SSE",Z,3)
5656 POKE214,19:PRINT:PRINT"------"T$"------";:GOTO5600
5660 GOSUB5900:GOSUB12500:CO$="THE ENEMY CAPTAIN":IFHTTHENZ=HT:GOSUB2290
5662 IFFT=0THENF$="BOARDING":GOSUB8097:X=3:Y=1:FF=36:GOSUB8590:GOSUB4140
5665 K=1:RETURN
5670 Z=-(FNGS(36)=2ORFT):FF=21+Z:ZZ=FNEX(PRS+128):IFZZ=-1THEN5675
5673 A=PEEK(PTY+20+ZZ)AND7:V=0:GOSUB4910:ZZ=A:GOSUB4290
5674 GOSUB2197:CO$=F$:FF=40
5675 GOSUB12500
5676 C1=6:GOSUB5900:X=1:Y=14:GOSUB8590:IFKANDFT=0THENGOSUB4155:C1=4
5677 IFDD<12ANDK=0THENWA=WA+24-2*DD
5678 IFFT=0THENGOSUB7880
5679 RETURN
5680 POKE214,22:PRINT:V=9:GOSUB5685
5681 F$="SINKING":XX=1:X=-19:Y=1:C1=14:C2=9:IFZ>=4THENGOSUB8100:GOTO5688
5682 POKE211,19:V=57:GOSUB5685
5683 IFZ<4THEN5600
5684 GOSUB8100:FF=24:GOSUB9900:C1=5:GOTO5676
5685 Z=INT(FNGS(V)/16)-1:IFZ<0THENRETURN
5686 T$="SAIL DAMAGE LOST A MAST HULL LEAKING":T$=MID$(T$,Z*12+1,12):PRINT" "T$;
5687 RETURN
5688 GOSUB5900:FF=23:X=1:Y=14:GOSUB8590:ZZ=0:V=0:GOSUB4910
5689 C=22:GOSUB8400:RETURN
5690 FF=25:IFFTTHENFF=42:GOTO5675
5691 GOTO5675
5700 GOSUB12500:K=1:XX=1:ZZ=-5:GOSUB4300:FF=26:GOTO5676
5710 T$="RAISING SAIL":IFFNGS(10)=1THENT$="LOWERING SAIL"
5715 GOTO5635
5720 V=10:GOSUB5739:GOTO5635
5730 V=63:GOSUB5739:POKE214,23:PRINT:PRINT,,T$;:GOTO5600
5739 T$="BATTLE SAILS":IFFNGS(V)=1THENT$="FULL SAILS  ":RETURN
5900 POKEVB+19,0:CX=(FNGS(58)+1)AND254:LN=FNGS(57):XM=FNGS(32):RETURN
5920 FORI=1TOPEEK(PTY+15):ZZ=PEEK(PTY+19+I):GOSUB4290:T$=T$+F$+" ":NEXTI:RETURN
5950 SG=-1:GOSUB8700:POKEVB+15,0:SL=SGN(SL):POKE198,0
5960 F=0:T=(PRS+128)/KP:L=.5:GOSUB12
5970 V=73:ZV=DF+(SK=PEEK(PRS+23)ANDDF>0)+DZ:IFZV>4THENZV=4
5980 GOSUB7:SK=0:POKES+15,99:POKES+18,128:POKE198,0:RETURN
5990 POKE816,165:POKE817,244:POKE818,237:POKE819,245::F=232:T=4:L=4:GOTO10
6000 V=1
6010 F$="":GOSUB12900:C1=248:C2=192:GOSUB9190:C1=252:C2=196:GOSUB9190
6020 V=4:ZV=Y(0):GOSUB7:V=56:ZV=T(0):GOSUB7:Z=(Y(0)*Y(1)+T(0)*T(1))/31
6030 V=5:ZV=INT(Y(0)*Y(1)/Z+.5)+8:GOSUB7:V=57:ZV=47-ZV:GOSUB7
6050 SK=1:GOSUB5950:DZ=0:V=3:ZV=C-2:GOSUB7:V=23:ZV=DL:GOSUB7
6100 Z=195.75:GOSUB12970
6105 ONPEEK(A0)GOTO6110,6110,6110,6130
6110 Y(0)=FNGS(4)
6120 V=2-PEEK(A0):GOSUB9190:C1=248:C2=192:GOSUB9190:RETURN
6130 POKE214,20:PRINT:PRINT"MORALE:",:ZV=INT(FNGS(57)/8)
6140 GOSUB6190:ZV=INT(FNGS(5)/8):GOSUB6190
6150 GOTO 6100
6190 PRINTMID$("PANIC SHAKENANGRY FIRM  STRONGWILD! WILD!!",ZV*6+1,6),:RETURN
6500 F$="SUNSIGHT":X=-10:Y=6:C1=0:C2=15:GOSUB8100:F$="SIGHT":GOSUB12900
6510 POKE214,21:PRINT:PRINT,"    LATITUDE: ?? N":GOSUB5950
6520 IFDF=0THENPRINT"   DEAD RECKONING LONGITUDE:"INT(96.7-PEEK(PTY+1)*.24)"W";
6600 GOSUB12950:ZZ=1:GOSUB9000:RETURN
6700 F$="SCAPE":GOSUB12900:GOSUB5950:V=23:ZV=CP:GOSUB7:GOSUB12500:F=15:T=216:L=4
6710 GOSUB12:F=4:T=232:L=4:GOSUB10:F=(DTA+410)/KP:T=(PRS+128)/KP:L=.1:GOSUB10
6712 V=33:ZV=FT:GOSUB7:GOSUB12950:GOSUB5990:IFFTTHENRETURN
6715 POKE214,21:PRINT:PRINT" PIRATE PARTY "," DEFENDERS "
6718 T$="     MEN     MUSKETS":PRINTT$;T$;
6720 T$="         TER: ":PRINTT$,T$;
6725 F$="BATTLE":GOSUB12900:V=23:ZV=CP:GOSUB7:DZ=0
6730 GOSUB12950:ZZ=0:GOSUB3980
6740 ONPEEK(A0)GOTO6750,6760,6770,6755
6750 Z=6
6752 ZV=INT(FNGS(Z)/16):POKE214,22:PRINT:POKE211,Z*1.3+34:GOSUB6190:GOTO6730
6755 Z=21:GOTO6752
6760 V=1
6765 WA=WA+FNGS(7)/99:GOSUB12500:IFV=0THENX=3:Y=3:FF=62:GOSUB8590
6767 RETURN
6770 V=0:GOTO6765
7000 F$="SHIP&S LOG":RR=1
7010 X=0:Y=0:DX=39:DY=24:GOSUB30:PRINT"","*** "F$" ***"
7020 K=PEEK(LG)-21:IFK<0THENK=-1:GOTO7060
7030 A=LG+K*4+1:Z=FNDP(A):I=PEEK(A+2):J=1-2*((I>9)AND(I<20))
7031 IF((JANDRR)=0)OR((Z>TVANDJ=3))THEN7060
7035 Z=Z-360*INT(Z/360):ZZ=INT(Z/30)
7040 GOSUB1099:PRINT""T$;
7045 Z=(Z-ZZ*30+1):PRINTZ;:POKE211,8:PRINT"-";
7048 Z=PEEK(A+2):ONINT((Z-1)/10)GOTO7052,7053
7050 ONZGOSUB7110,7120,7130,7140,7150,7160,7162,7164,7170,7180:GOTO7060
7052 ONZ-10GOSUB7190,7200,7210,7220,7230,7240,7255,7250,7260,7270:GOTO7060
7053 ONZ-20GOSUB7280,7300,7310,7320,7330,7340:GOTO7060
7060 K=K+1:IFK<PEEK(LG)THEN7030
7070 PRINT,"... THE END ...";:GOSUB2990
7090 RETURN
7110 PRINT"VISITED";
7115 A=CTY+(PEEK(A+3)AND63)*CLN:GOSUB2950:PRINT" "C$".":RETURN
7120 Z=INT(PEEK(A+3)/64):GOSUB2195
7125 PRINT"TITLED AS A "CO$;F$""RK$(PEEK(A+3)AND63)".":RETURN
7130 PRINT"PLUNDERED";:GOTO7115
7140 PRINT"CAPTURED A ";
7145 Z=INT(PEEK(A+3)/16):GOSUB2195:PRINTCO$;F$;"";
7146 ZZ=PEEK(A+3)AND15:GOSUB4290:PRINT""F$:RETURN
7150 PRINT"SANK A ";:GOTO7145
7160 PRINT"ENGAGED A ";:GOTO7145
7164 PRINT"FOUND BURIED TREASURE!":RETURN
7170 Z=PEEK(TR+24+4*8+INT(PEEK(A+3)/64)*8+1):GOSUB2290
7171 PRINT" "CO$" IN";:GOTO7115
7180 ZZ=PEEK(A+3):GOSUB7245:PRINT"OFFERS PIRATE AMNESTY!":RETURN
7190 PRINT"INDIANS ATTACK";:GOTO7115
7200 PRINT"NEW GOLD MINE AT";:GOTO7115
7210 PRINT"MALARIA STRIKES";:GOTO7115
7220 PRINT"NEW GOVERNOR IN";:GOTO7115
7230 PRINT"PIRATES PLUNDER";:GOTO7115
7240 ZZ=PEEK(A+3):GOSUB7245:PRINT"AT WAR WITH ";:GOSUB7245:PRINT".":RETURN
7245 F$=MID$("SPAIN  ENGLANDFRANCE HOLLANDPIRATE ",(ZZAND3)*8+1,8)
7246 GOSUB2197
7247 PRINTF$"";:ZZ=INT(ZZ/4):RETURN
7250 ZZ=PEEK(A+3):GOSUB7245:PRINT"ALLIES WITH ";:GOSUB7245:PRINT".":RETURN
7255 ZZ=PEEK(A+3):GOSUB7245:PRINT"AND ";:GOSUB7245:PRINT"MAKE PEACE.":RETURN
7260 ZZ=PEEK(PEEK(A+3)*CLN+CTY+3):GOSUB7245:PRINT"CAPTURES";:GOTO7115
7270 PRINT"TREASURE FLEET IN";:GOTO7115
7280 PRINT"SILVER TRAIN IN";:GOTO7115
7320 PRINT"CAPTURED THE TREASURE FLEET":RETURN
7330 PRINT"CAPTURED THE SILVER TRAIN":RETURN
7340 Z=PEEK(A+3):GOSUB8430:PRINT"RESCUED MY ";T$:RETURN
7880 C2=PEEK(SA)+PEEK(SA+1)*16:GOTO7900
7890 C2=(CP-CTY)/CLN
7900 AA=PEEK(LG):IFAA>=62THENT=LG/KP:F=T+.5:L=.5:GOSUB10:AA=AA-32
7910 POKELG,AA+1:AA=LG+1+AA*4:POKEAA+2,C1:POKEAA+3,C2
7920 C1=DAY+360*YR:POKEAA,FNLB(C1):POKEAA+1,C1/KP:RETURN
7999 X=20-INT(LEN(T$)/2):Y=20:GOSUB8005:FORI=0TO200:NEXTI:RETURN
8000 C=0:GOTO8009
8005 C=1
8009 IFSG>=0THENGOSUB8700
8010 AX=PRS+131:POKEAX-1,0:POKEVB+15,1:T$=""+T$:SYSWN+12:XL=PEEK(AX-2):DX=XL+2
8015 N=PEEK(AX-3):DY=N+1:CO=2+6*RND(0):IFABS(AA-TR)<=16THENCO=7
8016 IF(DX+X)>39THENDX=39-X
8017 IF(DY+Y)>24THENDY=24-Y
8020 GOSUB30:POKESP,176:Z=AX+PEEK(AX-1)
8030 POKE214,Y:PRINT"";:FORI=AX+NTOAX+1STEP-1:POKE211,X+1:IFZ=ITHENPRINT"";
8040 PRINTMID$(T$,PEEK(I)+2,PEEK(I-1)-PEEK(I))
8045 NEXTI:PRINT"";:IFCTHENRETURN
8050 IFPEEK(VB+18)ORPEEK(VB+14)THEN8050
8055 Z=N-Z+AX:POKEVB+16,X*4+7:POKEVB+17,(Y+Z)*8+60:POKE53269,1:IFZ>=NTHEN2990
8060 C=INT(PEEK(VB+17)/8)-7-Y:IFC<ZTHENC=Z
8070 IFC>=NTHENC=N-1
8071 L=PEEK(216*KP+(Y+C)*40+X+42)AND15:POKEA0,X+1:POKEA1,Y+C+1:POKEA2,0:SYSWN+15
8072 GOSUB8090:IFPEEK(VB+14)THENPOKEVB+16,0:POKEA2,6*SGN(L):SYSWN+15:RETURN
8074 POKEA2,L:SYSWN+15:GOSUB8090:GOTO8060
8080 POKEVB+16,0:POKE53269,0:RETURN
8090 FORI=0TO20:IFPEEK(VB+14)THENI=999
8091 NEXTI:RETURN
8095 X=1:Y=1:GOTO8099
8096 X=17:Y=1:GOTO8099
8097 X=1:Y=9:GOTO8099
8098 X=17:Y=9
8099 C1=0:C2=10:XX=XX+1
8100 F=236:IFX>0ANDRND(0)>PXTHENRD=0:RETURN
8110 T=161:L=2:GOSUB10:F$=F$+".WIN":BF=232*KP:GOSUB17800:IFXXTHENGOSUB12500:XX=0
8115 Z=ABS(X)+Y*40+41:RR=216*KP+Z:Z=PEEK(648)*KP+Z
8120 POKEA0,ABS(X):POKEA1,Y:POKEA2,19-18*(X=-1):POKEA3,15:POKEA4,0:SYSWN
8130 POKE53282,C1:POKE53283,C2:F=232:T=228:L=6:GOSUB10:F=161:T=236:L=2:GOSUB10
8140 POKEA0,FNLB(Z):POKEA1,Z/KP:POKEA2,FNLB(RR):POKEA3,RR/KP:SYSWN+9
8145 IFRDTHENPOKEA0,RD:POKEA1,RND(0)*6+10:SYSWN+18:RD=0
8150 IFX=-1THENX=0:Z=Z+18:RR=RR+18:GOTO8140
8160 PX=.7-DF*.15:RETURN
8180 GOSUB9900:GOSUB9900:SG=2:POKECP,PEEK(CP)OR128
8181 XX=1:X=-11:Y=9:F$="HAPPY":RD=14:GOSUB8099:X=2:Y=1:FF=52:GOSUB8590
8182 X=12:Y=4:Z=INT((WA-12)/15):IFZ>2THENZ=2
8183 IFZ>-1THENCO$=MID$("SOMEMUCHMOST",Z*4+1,4):FF=41:GOSUB8590
8190 GOSUB2250:FORI=1TO4:T(I)=INT(RND(0)*PEEK(CP+8))-50*(I=0):P(I)=0:NEXTI:F$=C$
8191 P(0)=0:T(0)=INT(PEEK(CP+7)*1500/(15+WA)):FORK=1TO2:IFCC<>PEEK(PR-K)THEN8194
8192 POKEPR-K,255:C1=23+K:GOSUB7900:X=8:Y=10:FF=49+K:GOSUB8590
8193 T(0)=T(0)+20*PEEK(DTA+KP+20*7+5):POKEPRS+26+K,16
8194 NEXTK:POKECP+7,FNRG(PEEK(CP+7)-T(0)/50):POKECP+8,FNRG(PEEK(CP+8)-20)
8195 C=-NN-8:GOSUB8400:IFT(0)>99THENGOSUB8400:GOSUB8400:C=4:GOSUB8400:GOSUB8400
8196 POKECP+9,(PEEK(CP+9)-3)AND255:IFME<PEEK(CP+6)*10*(1+RND(0))THEN8199
8197 X=3:Y=3:FF=39:GOSUB8590:POKECP+3,C-5:POKECP+9,2:POKECP+11,RND(0)*16
8198 IFC-5<>NNTHENPOKEPR+3+C,(PEEK(PR+3+C)+3)AND255:C=-NN-8:GOSUB8400:GOSUB8400
8199 T(4)=6*PEEK(CP+4):C1=3:GOSUB7890:T$="TOWN":GOTO8210
8200 GOSUB12500
8210 ZZ=(P(0)<>0ORT(0)=0):POKESP,176:X=1:Y=-ZZ:DX=37:DY=11+ZZ:CO=4*P(0):GOSUB30
8212 F$="":GOSUB12900:POKE53269,1
8220 POKE214,1:PRINT:PRINT,NA$," "T$,:CO$="":IFP(0)THENPRINT" PRICE":CO$=""
8225 POKE214,8:PRINT:PRINT"  USE JOYSTICK TO TRANSFER CARGO,":POKEVB+17,107
8226 PRINT"  PRESS TRIGGER WHEN DONE."
8227 IFZZ=0THENPRINT"",T(0)"0 GOLD PCS. PLUNDERED!":ZZ=-T(0):GOSUB3990:T(0)=0
8230 POKE214,2:PRINT:PRINT"GOLD","      "P$,CO$"     "P$:T$="     TONS"
8235 PRINT"FOOD",T$,T$,CO$;P(1)P$
8236 PRINT"GOODS",T$,T$,CO$;P(2)P$
8240 PRINT""X$,T$,T$,CO$;P(3)P$
8245 PRINT"CANNON",,,CO$;P(4)P$
8246 PRINT"SPACE IN HOLD:";T$:IFCX<0THENCX=CX+KK
8250 GOSUB5950:V=7:ZV=T(0):GOSUB7
8255 FORI=1TO4:V=11+I:ZV=T(I):GOSUB7:V=15+I:ZV=P(I):GOSUB7
8260 NEXTI:V=26:ZV=VA:GOSUB7:POKEVB+15,1
8270 Z=181.5:GOSUB12970:POKE53269,0:RETURN
8290 Y(0)=1:Y(1)=9:T(0)=1:T(1)=9:DL=1:GOTO8305
8300 DL=0
8305 GOSUB12500:X=-1:Y=2:C1=11:C2=9:GOSUB8100:F$=T$
8308 X=23:Y=17:T$="WHICH WEAPOWILL YOU USE RAPIE LONGSWOR CUTLAS":GOSUB8000
8310 T$=F$:POKEA0,1:POKEA1,18:POKEA2,30:POKEA3,4:POKEA4,2:SYSWN
8315 CO$="":F$="":IFLEN(T$)<12ANDDL=0THENZ=NN:GOSUB2195
8320 PRINT"",NA$" VS. "CO$;F$;"";T$:IFLEN(T$)>10THENT$="ENEMY"
8330 POKE214,18:PRINT:PRINT,T$,NA$:PRINT"FORCE:","   MEN","   MEN"
8350 GOSUB6000:GOSUB12500:X=2:Y=2
8388 IFV<>1ANDDLTHENFF=32:GOSUB8590:POKEPRS+4,255:GOTO8393
8389 IFV=-1THEN8395
8392 IFDL=0THENZZ=Y(0)-ME:GOSUB3980
8393 POKESP,176:RETURN
8395 C=22:GOSUB8400:X=-2:Y=9:XX=1:C1=0:C2=12:F$="PRISON":GOSUB8100:X=1:Y=1
8396 A=CP:GOSUB2950:A$=C$:FF=33:IFNN<>PEEK(CP+3)ORCC>NCTHENC$="THE SHIP"
8397 GOSUB8595:F$="ISLAND"
8398 IFC$=A$THENGOSUB12900:GOSUB5950:V=23:ZV=CP:GOSUB7:GOSUB12950:SL=FNGS(3)
8399 C$=A$:GOSUB4990:FF=3:X=6:Y=10:GOSUB8590:V=0:RETURN
8400 POKEPRS+ABS(C),(PEEK(PRS+ABS(C))+SGN(C))AND255
8404 C1=ABS(C)-8:A=PRS+64+C1*4:IFC1<0ORC1>3THENRETURN
8406 FORI=0TO3:POKEPRS+8+I,(PEEK(PRS+8+I)+SGN(C)*SGN(FNEX(A+I))AND255)
8408 NEXTI:RETURN
8410 POKEPTY+ABS(C),(PEEK(PTY+ABS(C))+SGN(C))AND255:RETURN
8420 Z=INT(FNEX(PRS+4)/4)*10+11:IFZ<1THENZ=1
8421 IFZ>51THENZ=51
8422 F$=MID$("COWARDLY  PROMISING WELL KNOWNFAMOUS    NOTORIOUS INFAMOUS!",Z,10)
8423 GOSUB2197:RETURN
8430 T$=MID$("SISTERFATHERMOTHERUNCLE ",Z*6+1,6):RETURN
8435 Z=INT((YR-PEEK(PRS+19)+PEEK(PRS+22))/(3-(PEEK(PRS+23)=4))):IFZ>4THENZ=4
8436 T$=MID$("FINEGOODFAIRPOORPOOR",Z*4+1,4):RETURN
8440 Z=INT(FNEX(PTY+17)/4)+1:IFZ>3THENZ=3
8441 IFZ<0THENZ=0
8442 F$=MID$("ANGRY  UNHAPPYPLEASEDHAPPY  ",Z*7+1,7):RETURN
8445 F$=MID$("APPRENTICEJOURNEYMANADVENTURERSWASHBCKLR",DF*10+1,10):RETURN
8450 Y(0)=ME:Y(1)=Y(1)+FNEX(PTY+17)/2:RETURN
8500 T$="NOT ENOUGH CREWONE SHIP LOST":X=10:Y=6:IFLLAND1THENRETURN
8505 IFPEEK(PTY+15)*8>METHENZZ=PEEK(PTY+15)-1:GOSUB8000:GOSUB4905:GOTO8500
8520 GOSUB8580:IFZ>=0THENRETURN
8530 GOSUB12500:T$="TOO MUCH CARGO":GOSUB7999
8540 T$="OVERBOARD":FORI=0TO4:T(I)=0:P(I)=0:NEXTI:GOSUB8210:GOTO8500
8580 Z=INT(PEEK(PTY+5)/2):FORI=9TO11:Z=Z+PEEK(PTY+I):NEXTI
8585 Z=PEEK(PTY+14)*10-Z:RETURN
8590 GOSUB8600:T$=T$+"":GOSUB8000:RETURN
8595 GOSUB8600:T$=T$+"":GOSUB8005:RETURN
8600 T$=""
8610 RR=PEEK(53269):POKE53269,0:OPEN15,8,15:OPEN5,8,5,"#"
8615 PRINT#15,"B-R:";5;0;INT(FF/21)+1;FF-INT(FF/21)*21
8620 INPUT#5,F$:IFF$="CO$"THENT$=T$+CO$:GOTO8620
8622 IFF$="C$"THENT$=T$+C$:GOTO8620
8625 Z=LEN(F$):IFF$="ZZ"THENT$=T$+MID$(STR$(ZZ),2)+" ":GOTO8620
8626 IFF$="ZZ0"THENT$=T$+MID$(STR$(ZZ),2)+"0 ":GOTO8620
8630 IFST=0THENT$=T$+LEFT$(F$,Z-1)+CHR$(ASC(MID$(F$,Z))+128):GOTO8620
8640 T$=T$+F$:CLOSE5:CLOSE15:POKE53269,RR:RETURN
8700 SG=4*KP+ABS(SG)*100+2*(SG<0)
8710 POKEA0,FNLB(SG):POKEA1,SG/KP:POKEA3,32
8720 POKES+3,2:POKES+10,2:POKES+17,2:POKEA4,9:POKEA5,10:SYSVB+9:SG=-1:RETURN
9000 CX=DAY:DAY=DAY+ZZ:IFINT(CX/30)=INT(DAY/30)THENRETURN
9020 FORMN=INT(CX/30)+1TOINT(DAY/30):GOSUB9100:GOSUB9180:IFLLTHEN9030
9022 IFFNEX(PTY+17)>-4THEN9028
9025 X=4:Y=4:GOSUB12500:FF=29:GOSUB8590:ZZ=-ME/3:GOSUB3975:DZ=1
9026 F$="DECK":T$="MUTINEER":GOSUB8290:POKEPRS+7,(PEEK(PRS+7)-4)AND255:GOTO9030
9028 IFFNEX(PTY+17)<0THENGOSUB12500:FF=27:GOSUB8590
9030 MT=-1:VV=VV*(LLAND2)/2:NEXTMN:IFDAY>=360THENDAY=DAY-360:YR=YR+1
9040 MN=INT(DAY/30):RETURN
9100 ZZ=MN:GOSUB1099
9104 T$=T$+STR$(1560+SN*20+YR+INT(MN/12))+""
9106 X=9:Y=9:GOSUB8005:ZZ=PEEK(PRS+5)/2:GOSUB3995
9110 F$="":GOSUB12900:GOSUB5950:V=19:ZV=MN:GOSUB7:V=22:ZV=NC:GOSUB7
9120 Z=183:GOSUB12970
9130 FORI=PRS+128TOPRS+136STEP2:C1=PEEK(I):IFC1THENC2=PEEK(I+1):GOSUB7900
9140 NEXTI:RETURN
9180 Z=2*SQR(FNDP(PTY+7)/FNDP(PTY+3))
9185 POKEPTY+17,(Z-FNEX(PRS+7)+4-DF)AND255:RETURN
9190 F=C1:T=232:L=4:GOSUB10:F=C2:T=C1:GOSUB10:F=232:T=C2:GOSUB10:RETURN
9250 AA=TR+24+4*8:IFPEEK(AA+24)THENRETURN
9270 GOSUB9300:POKEAA+2,6:Z=PEEK(PRS+6):GOSUB8430:A$=C$:C$=T$
9280 F$="SPANIARD":GOSUB3391:X=2:Y=2:FF=12:GOSUB8590
9285 C1=9:C2=ZZ+(AA-TR-56)*8:GOSUB7900
9290 A=ZZ*CLN+CTY:GOSUB2950:FF=0:X=1:Y=10:GOSUB8590:C$=A$:RETURN
9300 IFPEEK(AA)THENAA=AA+8:GOTO9300
9310 ZZ=INT(RND(0)*NC+1):IFPEEK(CTY+ZZ*CLN+3)THEN9310
9320 POKEAA,1:POKEAA+3,ZZ:FORI=AA+4TOAA+7:POKEI,0:NEXTI
9330 Z=RND(0)*32:POKEAA+1,Z:GOSUB2290:RETURN
9900 POKECP+8,FNRG(PEEK(CP+8)-10):RETURN
9950 POKECP+8,FNRG(PEEK(CP+8)+10):RETURN
12000 S=54272:POKES+18,129:SYSVB
12040 SX=53248:SY=SX+1:SC=53287:SP=204*KP+1016:RETURN
12500 POKEVB+13,0:POKE648,204:POKE53272,48+8
12510 POKE53269,0:POKE53271,0:POKE53277,0:POKE53276,0:POKE53270,24:POKE53265,27
12515 PRINT"";:POKE53280,14:POKE53281,1:POKE53282,0:MO=1
12520 RETURN
12900 F=0:T=VA/KP:L=.5:GOSUB12
12910 IFF$=SD$ORF$=""THENT=(VA+160)/KP:L=4-160/KP:GOSUB12:RETURN
12920 SD$=F$:F$=F$+".SID":BF=173.5*KP
12930 GOSUB17800:IF(ST AND191)<>0THEN12930
12940 F$="":GOTO12910
12950 POKEA0,128:POKEA1,173:SYSVAR-24:RETURN
12970 POKEA0,FNLB(Z*KP):POKEA1,Z:SYSVAR-24:RETURN
17700 POKE53269,0:SYSVB+3:GOSUB41:OPEN15,8,15,"I":PRINT#15,"S0:"+F$:CLOSE15
17705 GOSUB19520:POKE251,FNLB(BF):POKE252,BF/KP:POKEA1,FNLB(BF+LN)
17710 POKEA2,(BF+LN)/KP:POKEA0,251:POKEA4,216:POKEA5,255:SYSKE
17720 GOSUB40:SYSVB:RETURN
17800 RR=0
17805 SYSVB+3:GOSUB41:GOSUB19520
17806 RR=PEEK(53269):POKE53269,0:POKEA1,FNLB(BF):POKEA2,BF/KP
17810 POKEA0,0:POKEA4,213:POKEA5,255:SYSKE:POKE53269,RR:GOSUB40:SYSVB:RETURN
17900 RR=255:GOTO17805
19000 DEFFNDP(X)=PEEK(X)+256*PEEK(X+1):DEFFNGS(X)=PEEK(VA+2*X)+KP*PEEK(VA+2*X+1)
19001 DEFFNLB(X)=(X-32768)AND255:DEFFNEX(X)=PEEK(X)+256*(PEEK(X)>127)
19002 DEFFNRG(X)=-X*(X>=0ANDX<256)-255*(X>255)
19003 A0=165:A1=A0+1:A2=A1+1:A3=A2+1:A4=A3+1:A5=A4+1:A6=A5+1:KP=256:KK=KP*KP
19004 K=149*KP:SB=K+41:MVB=K+70:KE=K+142:S64K=K+29:M64K=K+20
19010 VAR=159*KP:RETURN
19520 FORI=0TOLEN(F$)-1:POKE830+I,ASC(MID$(F$,I+1,1)):NEXTI
19526 POKEA0,0:POKEA1,8:POKEA2,1:POKEA4,186:POKEA5,255:SYSKE
19528 POKEA0,LEN(F$):POKEA1,62:POKEA2,3:POKEA4,189:POKEA5,255:SYSKE:RETURN
21000 GOSUB12500:T$="GAME DISK SIDE 1":GOSUB2490:IFA$<>"1"THEN21000
21900 POKEPRS+21,YR:PRINT"LOAD "CHR$(34)"LIFE"CHR$(34)",8,1RUN"
21910 SYSVB+3:PRINT,"ONE MOMENT PLEASE...";
21920 GOSUB41:POKE631,13:POKE632,13:POKE198,3:NEW
